Regularne aktualizowanie systemu RouterOS to fundament bezpieczeństwa każdej sieci. Jednak umówmy się – mało kto ma czas na codzienne logowanie się do WinBoksa tylko po to, by sprawdzić przycisk „Check for Updates”. A co, jeśli Twój router sam mógłby Cię poinformować o dostępności nowej wersji?

W tym artykule pokażę Ci, jak przygotować automatyczne powiadomienie o aktualizacji MikroTik. Wykorzystamy do tego prosty skrypt oraz harmonogram zadań (Scheduler), dzięki czemu będziesz trzymać rękę na pulsie bez zbędnego wysiłku. Rozwiązanie to sprawdza się świetnie zarówno przy jednym urządzeniu, jak i przy zarządzaniu całą flotą routerów.

Aby Twój MikroTik sam dawał Ci znać o nowym oprogramowaniu, musimy przejść przez trzy kroki: konfigurację poczty, stworzenie skryptu i ustawienie harmonogramu.

Krok 1: Konfiguracja serwera E-mail
Zanim router wyśle wiadomość, musi wiedzieć, przez jaki serwer ma to zrobić. Najłatwiej użyć konta Gmail lub innego dostawcy (pamiętaj o wygenerowaniu „Hasła aplikacji”, jeśli używasz 2FA).

Wpisz w terminalu (lub wypełnij w WinBox: Tools -> Email):

/tool e-mail
set address=smtp.gmail.com port=587 start-tls=yes from=twoj_email@gmail.com user=twoj_email@gmail.com password=SuPeRtAjNeHaSlO

W powyższym kodzie podmień dane na poprawne dla twojego adresu e-mail.

Krok 2: Skrypt sprawdzający aktualizacje
Teraz stworzymy skrypt, który sprawdzi dostępność nowej wersji. Jeśli numer wersji na serwerze będzie inny niż ten zainstalowany, router wyśle do Ciebie e-mail.

Przejdź do System -> Scripts i dodaj nowy skrypt o nazwie CheckUpdate:

:log info "Skrypt CheckUpdate by PGKOMP.PL"
:local recipient "odbiorca@gmail.com"

/system package update check-for-updates
:delay 3s;
:local installed [/system package update get installed-version];
:local latest [/system package update get latest-version];

# Pobranie wolnego miejsca w bajtach
:local freeBytes [/system resource get free-hdd-space]
# Przeliczenie na MB (Dzielenie przez 1048576)
:local freeMB ($freeBytes / 1048576)

:local licznik 0;
:local listaip "";
:foreach addresslist in=[/ip address find] do={
:set $licznik ($licznik+1);
:local adres [/ip address get $addresslist address];
:set $listaip ($listaip . "$adres\r\n");
}

:if ($installed != $latest) do={
    :log info "Znaleziono nową wersję: $latest. Wysyłam e-mail."
    /tool e-mail send to=$recipient subject="Dostępna aktualizacja MikroTik ($[/system identity get name])" \
    body="Dostępna jest nowa wersja systemu RouterOS dla urządzenia $[/system resource get board-name]!\n\nWersja zainstalowana: $installed\nWersja najnowsza: $latest\n\nZaloguj się, aby przeprowadzić aktualizację.\r\rUptime: $[/system resource get uptime]\r\nVersion: $[/system resource get version]\r\nCpu-count: $[/system resource get cpu-count]\r\nCpu-frequency: $[/system resource get cpu-frequency] MHz\r\nFree-hdd-space: $freeMB MB\r\nArchitecture-name: $[/system resource get architecture-name]\r\nBoard-name: $[/system resource get board-name]\r\nPlatform: $[/system resource get platform]\r\rAddress:\r$listaip"
} else={
    :log info "System MikroTik jest aktualny ($installed)."
}

Krok 3: Harmonogram (Scheduler)
Ostatni etap to zautomatyzowanie procesu, aby router sprawdzał aktualizacje np. raz dziennie o 8:00 rano.

Wpisz w terminalu (lub System -> Scheduler):

/system scheduler
add name=DailyUpdateCheck interval=1d start-time=08:00:00 on-event=CheckUpdate

Wersja Stable vs Long-term: Na tym konkretnym modelu, jeśli używasz go w domu, polecam kanał Stable dla wersji 7.x. Jeśli jednak router służy tylko jako prosty punkt dostępowy i zależy Ci na „świętym spokoju”, zostań przy Long-term.

Więcej na temat wersji systemu MikroTik znajdziesz tu.

Bezpieczeństwo: Pamiętaj, aby po aktualizacji systemu zawsze zaktualizować również RouterBOARD firmware (w menu System -> Routerboard kliknij Upgrade i zrestartuj urządzenie).